home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (PO) / Bits and Bytes Volume 10, No. 03 (1988-10)(Apple Computing Enjoyment Society)(Side B).zip / Bits and Bytes Volume 10, No. 03 (1988-10)(Apple Computing Enjoyment Society)(Side B).po / CONCERT.LASER.bas < prev    next >
BASIC Source File  |  1996-12-24  |  6KB  |  127 lines
  1. 10  REM  * PROGRAM BY DARREL RAINES
  2. 20  REM  *
  3. 30  REM  * SOME ROUTINES HAVE APPEARED IN SOFTDISK AT EARLIER DATES
  4. 40  REM  * LAST UPDATE 2/2/84
  5. 50  REM  * ALL NEW MATERIAL BY DARREL RAINES
  6. 60  REM  *
  7. 70  REM  * SORRY, THERE WASN'T ENOUGH TIME TO DOCUMENT FULLY!
  8. 100  TEXT : HOME : SPEED= 255
  9. 110  VTAB 5: HTAB 5: PRINT "HURRY, HURRY! GET YOUR TICKETS HERE"
  10. 120  PRINT  CHR$(4);"BLOAD PLAYER,A$300"
  11. 130  VTAB 8: HTAB 6: PRINT "IT'S THE GREATEST SHOW ON EARTH..."
  12. 140  PRINT  CHR$(4);"BLOAD CL.SHAPES,A$7000"
  13. 150  VTAB 11: HTAB 7: PRINT "A LASER LIGHT SHOW OF BEAUTY."
  14. 160  PRINT  CHR$(4);"BLOAD PIANO.CARTOON,A$6000"
  15. 170  VTAB 14: HTAB 8: PRINT "PIANO CONCERT EXTRAORDINARE!"
  16. 180  PRINT  CHR$(4);"BLOAD M.HUNGARIAN.DAN,A$4000"
  17. 185  VTAB 17: HTAB 9: INVERSE : PRINT "HURRY, HURRY!!": NORMAL 
  18. 190  PRINT  CHR$(4);"BLOAD SHAPE.SUB,A$1B00"
  19. 200 T1$ = "** DARREL RAINES PRESENTS **"
  20. 210 T2$ = "CARNAGIE HALL"
  21. 220 T3$ = "LASER SHOW AND PIANO CONCERT"
  22. 230  GOSUB 21200
  23. 240  FOR I = 1 TO 2000: NEXT I
  24. 250  TEXT : HOME 
  25. 260  VTAB 22: HTAB 12: PRINT "LASER LIGHT SHOW"
  26. 270  FOR I = 600 TO 634
  27. 280  READ X: POKE I,X: NEXT I
  28. 300  HGR 
  29. 310  HCOLOR= 3
  30. 320  FOR Y = 0 TO 159  STEP 3
  31. 325  HPLOT 0,0 TO 279,Y
  32. 326  NEXT Y
  33. 327  HCOLOR= 2
  34. 330  FOR Y = 1 TO 159  STEP 3
  35. 340  HPLOT 0,159 TO 279,Y
  36. 350  NEXT Y
  37. 360  HCOLOR= 1
  38. 370  FOR Y = 2 TO 159  STEP 3
  39. 380  HPLOT 279,79 TO 0,Y
  40. 390  NEXT Y
  41. 395  POKE 640,16: POKE 641,100: CALL 600
  42. 400  HCOLOR= 0
  43. 410  FOR IX = 140 TO 0  STEP  -2
  44. 420  HPLOT 70,10 TO 70,10 +IX TO 70 +IX,10 +IX TO 70 +IX,10 TO 70,10
  45. 430  NEXT IX
  46. 440  FOR IX = 139 TO 0  STEP  -2
  47. 450  HPLOT 70,10 TO 70,10 +IX TO 70 +IX,10 +IX TO 70 +IX,10 TO 70,10
  48. 460  NEXT IX
  49. 470  HCOLOR= 7
  50. 480  FOR Y = 10 TO 150  STEP 3
  51. 490  HPLOT 210,150 TO 70,Y
  52. 500  NEXT Y
  53. 505  HCOLOR= 6
  54. 510  FOR Y = 11 TO 150  STEP 3
  55. 520  HPLOT 210,10 TO 70,Y
  56. 530  NEXT Y
  57. 535  HCOLOR= 5
  58. 540  FOR Y = 12 TO 150  STEP 3
  59. 550  HPLOT 70,79 TO 210,Y
  60. 560  NEXT Y
  61. 565  POKE 640,15: POKE 641,100: CALL 600
  62. 570  HCOLOR= 0
  63. 580  FOR IY = 100 TO 0  STEP  -2
  64. 590  HPLOT 269,129 TO 110 -IY,129 TO 110 -IY,129 -IY TO 269,129 -IY TO 269,129
  65. 600  NEXT IY
  66. 605  FOR IY = 99 TO 0  STEP  -2
  67. 610  HPLOT 269,129 TO 110 -IY,129 TO 110 -IY,129 -IY TO 269,129 -IY TO 269,129
  68. 620  NEXT IY
  69. 625  FOR C = 3 TO 1  STEP  -1
  70. 630  HCOLOR= C
  71. 640  FOR X = 0 TO 100  STEP 5
  72. 650  HPLOT 13 -C +X,32 -C +X TO 266 +C -X,32 -C +X TO 266 +C -X,126 +C -X TO 13 -C +X,126 +C -X TO 13 -C +X,32 -C +X
  73. 660  NEXT X
  74. 670  NEXT C
  75. 673  POKE 640,16: POKE 641,100: CALL 600
  76. 675  HCOLOR= 0
  77. 680  FOR IY = 0 TO 35
  78. 690  HPLOT 55,44 +IY TO 224,44 +IY
  79. 700  HPLOT 55,114 -IY TO 224,114 -IY
  80. 710  NEXT IY
  81. 720  HOME 
  82. 730  VTAB 22: HTAB 7: PRINT "CONCERT -- HUNGARIAN DANCE"
  83. 800  CALL 24576
  84. 810  HOME 
  85. 820  VTAB 22: HTAB 16: PRINT "THE END"
  86. 900  FOR Y = 0 TO 159
  87. 910  HPLOT 0,Y TO 279,Y
  88. 920  NEXT Y
  89. 930  TEXT : HOME 
  90. 950  DATA  160,255,173,81,192,173,128,2
  91. 960  DATA  41,127,170,202,208,253
  92. 970  DATA  173,80,192,173,128,2
  93. 980  DATA  41,127,170,202,208,253
  94. 990  DATA  136,208,229,206,129,2,208,222,96
  95. 9999  ONERR  GOTO 10001
  96. 10000  PRINT : PRINT  CHR$(4)"RUNMENU"
  97. 10001  POKE 216,0: END 
  98. 21200  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>          <CTRL-M><CTRL-M>TITLE PAGE<CTRL-M>==========<CTRL-M>
  99. 21202  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>VARIABLES NEEDED:<CTRL-M>T1$: FIRST LINE OF TITLE<CTRL-M>T2$: SECOND LINE OF TITLE<CTRL-M>T3$: THIRD LINE OF TITLE<CTRL-M>
  100. 21204  IF  LEN(T1$) <34  THEN T1$ = T1$ +" "
  101. 21206  IF  LEN(T1$) <34  THEN T1$ = " " +T1$: GOTO 21204
  102. 21208  IF  LEN(T2$) <34  THEN T2$ = T2$ +" "
  103. 21210  IF  LEN(T2$) <34  THEN T2$ = " " +T2$: GOTO 21208
  104. 21212  IF  LEN(T3$) <34  THEN T3$ = T3$ +" "
  105. 21214  IF  LEN(T3$) <34  THEN T3$ = " " +T3$: GOTO 21212
  106. 21216  HOME : PRINT "*";: FOR Z = 1 TO 38: PRINT "^";: NEXT : PRINT "*<";: INVERSE : FOR Z = 1 TO 38: PRINT " ";: NEXT : NORMAL : PRINT "><";: INVERSE : PRINT " ";: NORMAL : PRINT "*";
  107. 21218  INVERSE :A$ = "''''!''''!''''!''''!''''!''''!''''": PRINT A$;: NORMAL : PRINT "*";: INVERSE : PRINT " ";: NORMAL : PRINT ">";
  108. 21220 B$ = "::::!::::!::::!::::!::::!::::!::::"
  109. 21222  FOR Z = 1 TO 8: PRINT "<";: INVERSE : PRINT " ";: NORMAL : PRINT ">";: INVERSE : PRINT B$;: NORMAL : PRINT "<";: INVERSE : PRINT " ";: NORMAL : PRINT "><";: INVERSE : PRINT " ";: NORMAL : PRINT ">";: INVERSE : PRINT A$;: NORMAL : PRINT "<";: INVERSE : PRINT " ";: NORMAL : PRINT ">";: NEXT 
  110. 21224  PRINT "<";: INVERSE : PRINT " ";: NORMAL : PRINT ">";: INVERSE : PRINT B$;: NORMAL : PRINT "<";: INVERSE : PRINT " ";: NORMAL : PRINT "><";
  111. 21226  INVERSE : PRINT " ";: NORMAL : PRINT ">";: FOR Z = 1 TO 34: PRINT "V";: NEXT : PRINT "<";: INVERSE : PRINT " ";: NORMAL : PRINT "><";
  112. 21228  INVERSE : PRINT " ";: NORMAL : PRINT "*";: FOR Z = 1 TO 34: PRINT "^";: NEXT : PRINT "*";: INVERSE : PRINT " ";: NORMAL : PRINT "><";
  113. 21230  INVERSE : FOR Z = 1 TO 38: PRINT " ";: NEXT : NORMAL : PRINT ">*";: FOR Z = 1 TO 38: PRINT "V";: NEXT 
  114. 21232  POKE 2039,170
  115. 21234  POKE 32,3: POKE 33,34: POKE 34,2: POKE 35,21
  116. 21236  FOR Z = 1 TO 500: NEXT 
  117. 21238  VTAB 21: FOR XZ = 1 TO 7: PRINT : FOR ZZ = 1 TO 12:X =  PEEK( -16336): NEXT : FOR Z = 1 TO 500: NEXT : NEXT 
  118. 21240  PRINT : FOR Z = 1 TO 12:X =  PEEK( -16336): NEXT 
  119. 21242  VTAB 14: PRINT T3$;: FOR Z = 1 TO 500: NEXT : POKE 35,13: VTAB 13
  120. 21244  PRINT : FOR ZZ = 1 TO 12:X =  PEEK( -16336): NEXT : FOR Z = 1 TO 500: NEXT 
  121. 21246  PRINT : FOR Z = 1 TO 12:X =  PEEK( -16336): NEXT 
  122. 21248  VTAB 12: PRINT T2$;: FOR Z = 1 TO 500: NEXT : POKE 35,11: VTAB 11
  123. 21250  PRINT : FOR ZZ = 1 TO 12:X =  PEEK( -16336): NEXT : FOR Z = 1 TO 500: NEXT 
  124. 21252  PRINT : FOR Z = 1 TO 12:X =  PEEK( -16336): NEXT 
  125. 21254  VTAB 10: PRINT T1$;: FOR Z = 1 TO 500: NEXT : POKE 35,9: VTAB 9
  126. 21256  FOR XZ = 1 TO 6: PRINT : FOR ZZ = 1 TO 12:X =  PEEK( -16336): NEXT : FOR Z = 1 TO 500: NEXT : NEXT 
  127. 21258  RETURN